.版本 2
.DLL命令 PostMessageA, 整数型, "user32.dll", "PostMessageA", , 如果函数调用成功，返回非零值：如果函数调用失败，返回值是零
  .参数 hWnd, 整数型, , 其窗口程序接收消息的窗口的句柄
  .参数 Msg, 整数型, , 指定被寄送的消息
  .参数 wParam, 整数型, , 指定附加的消息特定的信息
  .参数 IParam, 整数型, , 指定附加的消息特定的信息

.版本 2
.支持库 spec
.支持库 shell
.支持库 BmpOperate
.程序集 窗口程序集_启动窗口
.程序集变量 文件路径, 文本型
.程序集变量 开始, 逻辑型
.子程序 __启动窗口_创建完毕
窗口_热键注册 (取窗口句柄 (), 1, #A键, &_按钮_绘画_被单击, 1)
.子程序 _按钮_绘画_被单击
.局部变量 a, 整数型
.局部变量 b, 整数型
.局部变量 鼠标位置, 精易_坐标
程序_延时 (2000, )
鼠标位置 ＝ 鼠标_取位置 ()
调试输出 (1)
开始 ＝ 真
.计次循环首 (画板1.宽度, a)
  .计次循环首 (画板1.高度, b)
    .如果 (画板1.取点 (a, b) ＝ 0)
      程序_延时 (1)
      鼠标_移动 (, 鼠标位置.横 ＋ a, 鼠标位置.纵 ＋ b)
      鼠标_按键 (1, 3)
    .否则
      鼠标_按键 (1, 4)
    .如果结束
    系统_处理事件 ()
    .如果真 (开始 ＝ 假)
      跳出循环 ()
    .如果真结束
  .计次循环尾 ()
  .如果真 (开始 ＝ 假)
    跳出循环 ()
  .如果真结束
.计次循环尾 ()
调试输出 (2)
.子程序 _按钮_载入_被单击
通用对话框1.初始目录 ＝ 取特定目录 (3)
通用对话框1.过滤器 ＝ “PNG|*.png|JPG|*.jpg|BMP|*.bmp|JPGE|*.jpge”
通用对话框1.打开 ()
文件路径 ＝ 通用对话框1.文件名
画板1.底图 ＝ 读入文件 (通用对话框1.文件名)
画板1.底图 ＝ 清除杂点 (二值化处理 (画板1.取图片 (, ), 150), 0)
.子程序 二值化处理, 字节集
.参数 图片, 字节集
.参数 二值化值, 整数型
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 RGB, 字节集
.局部变量 颜色值, 整数型
位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
  .计次循环首 (位图.取宽度 (), x)
    RGB ＝ 到字节集 (位图.取某点颜色 (x － 1, y － 1))
    颜色值 ＝ (RGB [1] ＋ RGB [2] ＋ RGB [3]) ÷ 3
    .如果 (二值化值 ＜ 颜色值)
      位图.置某点颜色 (x － 1, y － 1, #白色)
    .否则
      位图.置某点颜色 (x － 1, y － 1, #黑色)
    .如果结束
  .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())
.子程序 清除杂点, 字节集
.参数 图片, 字节集, , 二值化后的图片
.参数 清除强度, 整数型, 可空, 默认为1
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 x_, 整数型
.局部变量 y_, 整数型
.局部变量 i, 整数型
.局部变量 a, 整数型
.如果真 (是否为空 (清除强度))
  清除强度 ＝ 1
.如果真结束
位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
  .计次循环首 (位图.取宽度 (), x)
    .如果真 (位图.取某点颜色 (x － 1, y － 1) ＝ #黑色)
      a ＝ 0
      .计次循环首 (8, i)
        x_ ＝ 多项选择 (i, 0, 1, 1, 1, 0, -1, -1, -1)
        y_ ＝ 多项选择 (i, -1, -1, 0, 1, 1, 1, 0, -1)
        .如果真 (位图.取某点颜色 (x － 1 － x_, y － 1 － y_) ＝ #黑色)
          a ＝ a ＋ 1
        .如果真结束
      .计次循环尾 ()
      .如果真 (a ≤ 清除强度)
        位图.置某点颜色 (x － 1, y － 1, #白色)
      .如果真结束
    .如果真结束
  .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())
.子程序 反色处理, 字节集
.参数 图片, 字节集
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 RGB, 字节集
位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
  .计次循环首 (位图.取宽度 (), x)
    RGB ＝ 到字节集 (位图.取某点颜色 (x － 1, y － 1))
    位图.置某点颜色 (x － 1, y － 1, 取颜色值 (255 － RGB [1], 255 － RGB [2], 255 － RGB [3]))
  .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())
.子程序 _按钮_黑白_被单击
画板1.底图 ＝ 清除杂点 (二值化处理 (画板1.取图片 (, ), 150), 0)
.子程序 _按钮_反色_被单击
画板1.底图 ＝ 反色处理 (画板1.取图片 (, ))
.子程序 _滑块条1_位置被改变
调试输出 (滑块条1.位置)
画板1.底图 ＝ 读入文件 (文件路径)
画板1.底图 ＝ 清除杂点 (二值化处理 (画板1.取图片 (, ), 滑块条1.位置), 0)